去除暴风影音的广告.bat(原)

@ECHO OFF
ECHO 屏蔽暴风影音广告
ECHO.
ECHO 作者：Shortway@Sina.com
ECHO.
ECHO 按任意键继续...
ECHO.
@PAUSE>NUL

REM 1、停止“Contrl Center of Storm Media”服务
ECHO 1、正在停止相关服务...
@NET STOP CCOSM>NUL 2>NUL
ECHO 设置完成！
ECHO.

REM 2、设置该服务为“禁用”
ECHO 2、正在禁用相关服务...
REM 注册表路径：[HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Services\ccosm]
REM 键名键值："Start"=dword:00000002
REM dword值说明：0：启动；1：系统；2：自动；3：手动；4：禁用；其它：(未知)
:loopTry
REM 用“REG ADD”命令修改注册表。要得到此命令的帮助，请键入: REG ADD /?
REG ADD HKLM\SYSTEM\CurrentControlSet\Services\ccosm /v Start /t REG_DWORD /d 4 /f>NUL 2>NUL
IF %ERRORLEVEL% EQU 1 GOTO loopTry
ECHO 设置完成！
ECHO.

REM 3、清除广告文件
ECHO 3、正在清除广告文件...
@IF EXIST "C:\Program Files\StormII\media\video_style_list.xml" (ATTRIB -S -H -A -R "C:\Program Files\StormII\media\video_style_list.xml" & DEL /F /S /Q "C:\Program Files\StormII\media\video_style_list.xml">NUL)
@IF EXIST "C:\Program Files\StormII\media\stcon.ini" (ATTRIB -S -H -A -R "C:\Program Files\StormII\media\stcon.ini" & DEL /F /S /Q "C:\Program Files\StormII\media\stcon.ini">NUL)
ECHO 屏蔽暴风影音广告 by Shortway>"C:\Program Files\StormII\media\video_style_list.xml"
ECHO 屏蔽暴风影音广告 by Shortway>"C:\Program Files\StormII\media\stcon.ini"
@ATTRIB +S +H +A +R "C:\Program Files\StormII\media\video_style_list.xml"
@ATTRIB +S +H +A +R "C:\Program Files\StormII\media\stcon.ini"
ECHO 清除完成！
ECHO.

ECHO --------------------------------------------------
ECHO.
ECHO 屏蔽暴风影音广告完成！
ECHO 按任意键退出...
@PAUSE>NUL